bootmac-bluetooth.service

-[Unit]
-Description=Set Bluetooth Mac Address
-PartOf=bluetooth.target
-
-[Service]
-Type=oneshot
-RemainAfterExit=yes
-ExecStart=/usr/bin/bootmac --bluetooth
-
-[Install]
-WantedBy=bluetooth.target

meson.build

+project(
+    'bootmac', 'c',
+    version: '0.6.0',
+    license : 'GPL-3.0-or-later',
+)
+
+prefix = get_option('prefix')
+bindir = prefix / get_option('bindir')
+libdir = prefix / get_option('libdir')
+
+pkg = import('pkgconfig')
+
+systemd = dependency('systemd', required : false)
+
+# udev is only used to get the rules location, we can have a fallback
+udev = dependency('udev', required : false)
+if udev.found()
+    udev_rules_dir = udev.get_variable(pkgconfig : 'udevdir') / 'rules.d'
+else
+    udev_rules_dir = libdir / 'udev' / 'rules.d'
+endif
+
+# By default, install the udev rules that execute bootmac directly
+bt_udev_rules = 'bootmac-bluetooth.rules'
+wifi_udev_rules = 'bootmac-wifi.rules'
+
+if systemd.found()
+    # On systemd-based system, install a specific udev rule for bluetooth, using
+    # unit activation and a template service we can instantiate for either
+    # bluetooth or wifi
+    systemd_system_unit_dir = systemd.get_variable(
+        pkgconfig : 'systemdsystemunitdir',
+        pkgconfig_define: ['prefix', prefix]
+    )
+
+    install_data(
+        'systemd/bootmac@.service',
+        install_dir: systemd_system_unit_dir
+    )
+
+    bt_udev_rules = 'systemd/bootmac-bluetooth.rules'
+endif
+
+install_data(
+    bt_udev_rules,
+    wifi_udev_rules,
+    install_dir: udev_rules_dir,
+    rename: [
+        '90-bootmac-bluetooth.rules',
+        '90-bootmac-wifi.rules'
+    ],
+)
+
+install_data(
+    'bootmac',
+    install_dir: bindir,
+    install_mode: 'rwxr-xr-x'
+)

systemd/bootmac-bluetooth.rules

+#
+# Configure the MAC addresses of the Bluetooth interface when it appears.
+# Copyright (c) Dylan Van Assche (2022)
+# SPDX-License-Identifier: GPL-3.0-or-later
+#
+
+ACTION=="add", SUBSYSTEM=="bluetooth", KERNEL=="hci0", TAG+="systemd", ENV{SYSTEMD_WANTS}+="bootmac@bluetooth.service"

systemd/bootmac@.service

+[Unit]
+Description=Set %i MAC address
+
+[Service]
+Type=oneshot
+RemainAfterExit=yes
+ExecStart=/usr/bin/bootmac --%i