Add separate udev rules for systemd installs, rework service

On systemd-based systemd, running bootmac directly from the udev rules doesn't work very well. As previously noted, using a systemd service instead fixes those problems, although it requires finding an appropriate "reverse dependency" (such as e.g. bluetooth.target).

Using unit activation from udev makes it easier, at it will be triggered once the interface exists. Moreover, in order to avoid creating multiple service files, we can make it a template and use the instance parameter as bootmac's main command-line argument.

meson.build

+project(
+    'bootmac', 'c',
+    version: '0.6.0',
+    license : 'GPL-3.0-or-later',
+)
+
+prefix = get_option('prefix')
+bindir = prefix / get_option('bindir')
+libdir = prefix / get_option('libdir')
+
+pkg = import('pkgconfig')
+
+systemd = dependency('systemd', required : false)
+
+# udev is only used to get the rules location, we can have a fallback
+udev = dependency('udev', required : false)
+if udev.found()
+    udev_rules_dir = udev.get_variable(pkgconfig : 'udevdir') / 'rules.d'
+else
+    udev_rules_dir = libdir / 'udev' / 'rules.d'
+endif
+
+# By default, install the udev rules that execute bootmac directly
+bt_udev_rules = 'bootmac-bluetooth.rules'
+wifi_udev_rules = 'bootmac-wifi.rules'
+
+if systemd.found()
+    # On systemd-based system, install a specific udev rule for bluetooth, using
+    # unit activation and a template service we can instantiate for either
+    # bluetooth or wifi
+    systemd_system_unit_dir = systemd.get_variable(
+        pkgconfig : 'systemdsystemunitdir',
+        pkgconfig_define: ['prefix', prefix]
+    )
+
+    install_data(
+        'systemd/bootmac@.service',
+        install_dir: systemd_system_unit_dir
+    )
+
+    bt_udev_rules = 'systemd/bootmac-bluetooth.rules'
+endif
+
+install_data(
+    bt_udev_rules,
+    wifi_udev_rules,
+    install_dir: udev_rules_dir,
+    rename: [
+        '90-bootmac-bluetooth.rules',
+        '90-bootmac-wifi.rules'
+    ],
+)
+
+install_data(
+    'bootmac',
+    install_dir: bindir,
+    install_mode: 'rwxr-xr-x'
+)